Channel Description:

Latest Articles in this Channel:

11/17/11--19:43: 第三课 台帐--报表--图形 (chan 2584942)

   

第三课   台帐--报表--图形

1.    台帐--报表--图形

    我们可以将图3-1看成一个小系统，由输入区、输出区和图形三个过程组成。输入区虽然列数不多，但可以把它看成是台帐；输出区看成是报表，是通过函数从台帐中取得数据；图形是根据报表利用图表向导功能制作的。可见，麻雀虽小，五脏俱全，能清晰地表达过程之间的输入与输出关系，形成一个相对完整的系统。对于输入区，可以是手工输入，或是由ERP、OA导出的表格。

    这里的项目是由A、B、C……字母组成，可以把它看成是质量问题、单位、供方、顾客、工序、车间等要素，数据统计分析，就是按要素（或条件）对频次或数量进行统计分析。有些要素是相对固定的，如单位、供方等；有些要素是设计出来的，如质量问题，是通过实践中归纳起来的，在设计要素时，要注意精炼，烦简得当。由要素可组成系统，可形成要素簇。对要素要进行管理，不可不察。

    在输入中，可注意用好Excel的两个序列（要素）：输入区对A、B、C……输入，可用“数据→有效性→序列”的方法进行；输出区对A、B、C……输入，可用“工具→选项→自定义序列”的方法进行。

    输出区的公式：

    E3：=COUNTIF($A$3:$A$2000,D3)         （条件求单元格的个数）

    F3：=SUMIF($A$3:A$2000,D3,B$3:B$2000)  （条件求和）

    以填充柄将E3：F3填充至E12：F12 。

    选中D3：E12，以“图表向导、柱形图”作频次统计图；选中“D3：D12，F3：F12”以“图表向导、柱形图”作数量统计图。对图形格式略。



图3-1

2.    由台帐到排列图

    在图3-2中由两张表格组成，一张是台帐（有很多行），登录问题描述和不合格数，一张是报表，是通过函数从台帐中求出数据，再由报表作排列图。

    排列图，又叫帕累托图。是为寻找影响质量的主要原因所使用的图。它应用了“关键的少数，次要的多数”的原理。在质量管理中，哪个质量问题是主要问题，产生质量问题的主要原因在哪里，找到问题后又该从哪里入手，排列图就是解决上述问题的一种有效方法。

    排列图最早是由意大利经济学家帕累托用来分析社会财富的分布情况而使用的图。他发现多数人占有少数财富，而少数人占有多数财富。这一现象在排列图上被描述为一条累积百分比曲线。为了纪念他，累积百分比曲线又叫做帕累托曲线。后来美国质量管理专家朱兰把这个原理应用于质量管理活动，成为常用的方法之一。

这里所作的排列图是一个单坐标排列图，即只有一个纵坐标。现在有三条表示80%、90%、100%的三条直线，已能清楚地表达排列图的要求。因为排列图的频数是由大到小排列的，当台帐的数据发生变化，报表中频数会随着变化，有时会不呈降序排列，这时，只要单击报表中左上角的“降序排列”，频数就会呈降序排列，图形也符合了排列图的要求。“降序排列”是通过录制的“宏”实现的，录制宏有如录音，这里是通过Excel中的“工具→宏→录制宏”记录了具体的降序的过程实现的，降序时，选中B3：C6，“其它”不参加降序，操作是“选中B3：C6→数据→排序→我的数据区域：无标题行→主要关键字：列C→降序”进行的。

    求作报表的公式是：

    C3：=SUMIF(台帐1!D$3:D$1000,B3,台帐1!E$3:E$1000)

    以填充柄拖拽C3至C7

    D3：=C3

    D4：=D3+C4

    以填充柄拖拽D4至D7

    E3：=$D$9*0.8

    F3：=$D$9*0.9

    G3：=$D$9*1

    以填充柄拖拽E3：G3至E7：G7

    选中B2：G17，利用图表向导进行作图，在选取图表类型时，频数为柱形图，累积数为折线图，三条直线为xy散点图，无数据点平滑线散点图。在对图形进行格式时，对三条直线的右端进行数据点格式，呈现80%、90%、100%，对柱形图进行格式时，“数据系列格式→选项→分类间距（W）为0”。



图3-2

3.    双坐标排列图

    实际上双坐标排列图是我们大家所欢迎的图形，但是它不能跟“台帐”联合使用，形成自动系统，因为对双坐标排列图的纵坐标轴的格式不能随着台帐的改变而改变，需要手工重新格式。

    双坐标轴的作图计算与单坐标轴大同小异，不妨将频数由手工输入，累积数和80%的计算公式与单坐标轴一样，只不过将90%和100%由手工输入09和1，增加了一个单元格计算1.10，这里是数据8724的1.1培，是对纵坐标轴进行格式的需要，这样，才能作如图3-3如此严谨和美妙的图形。1.1的计算公式是：=1.1*D9（D9是8724的单元格）。

    双坐标轴的作图与单坐标轴的作图也不一样。在利用图表向导作图时，单坐标轴是利用“标准类型”作图的，双坐标轴是利用“自定义类型”作图的，具体操作是：

    “选中B2：G9→图表向导→自定义类型→丙轴线柱图→标题→勾销图例→完成”

    “对80选择图表类型为XY散点图之无数据点平滑散点图→对累积数选择图表类型为折线图”

    “对左纵坐标轴格式：刻度：最小值：0→最大值：1.1培的值，这里是9596.40”

    “对右纵坐标轴格式：刻度：最小值：0→最大值：1.1→主要刻度单位：0.1→次要刻度单位：0.01”。至此，方能保证两纵坐标轴的完美匹配。



图3-3

4．单一零件的“收、发、存”

    下边（图3-4）是单一零件出入库的“流水帐”，这种形式也可是现金流水帐，都能在帐中反映出“收、发、存”。这种形式的自动计算可以通过编辑公式来完成：

    E3：手工输入接上期的入库数

    G3：=F3

    G4：=H3+F4-G4    （上次结余加本次收入减本次支出等于本次结余）

    以填充柄拖拽G4至Gn

    进行合计(打包)计算：

    I3：=SUM(F3:F2000)

    J3：=SUM(G3:G2000)

    K3：=J3-K3

    为什么叫“打包”？这是一个通俗形象的叫法，当一张一张像这样的表格需要进行分析时，有些表格比这张要复杂得多，将需要进行汇总分析的数据，整理到一行或一列中的单元格区域里，这里如“I3：K3”，形象地说叫“打包”，一拎就走。

    现模拟设计一个简易系统，假设有a1、a2、a3、a4、a5、a6、a7、a8……an个零件，则建立n张表格，一张表格记录一个零件的出入，图3-4是a1零件的计算。将a1零件的计算看成是一个“过程”，如图3-5下部，设计表格的“标签”，将a1零件的表格“复制—粘贴”成n张表格。

设计“产品出入库汇总表”，利用公式将每个零件的“打包”汇总过来，在单元格F2建立“数据—有效性—序列”，通过下拉箭头，调入“库存数”或“入库数”、“出库数”，选中单元格区域A2：A15，F2：F15”，作折线图，实现动态分析。

    图3-5的计算如下：

    B3：='a1'!J$3

    以填充柄拖拽B3至B15

    依次修改B4、 B5、 B6……，如B4：='a2'!J$3

    以填充柄拖拽B3：B15至D3：D15

    F3：=HLOOKUP(F$2,B$2:D$15,G3,FALSE)

    以填充柄拖拽F3至F15

    作图与格式略。



图3-4



图3-5

  




11/21/11--17:40: 第四课 一个台帐 两种思路 (chan 2584942)

 

第四课   一个台帐  两种思路

    人们往往苦于有台帐无报表可求，有报表无图形可作。本课试从一个台帐入手，导论此问题。

    现有一个台帐如图4-1，B至I列是手工登录或由ERP、SAP、OA中导入的数据。J、K列是为了进行数据分析所作的中间处理。

    从图4-1中能作哪些报表呢？我们将要素按一维表格、二维表格排列组合，一维表格：产品—数量、材料—数量、客户—数量、供方—数量、月份—数量；产品—金额、材料—金额、客户—金额、供方—金额、月份—金额。二维表格：产品—月份—金额、材料—月份—金额、客户—月份—金额、供方—月份—金额、供方—材料—金额；产品—月份—数量、材料—月份—数量、客户—月份—数量、供方—月份—数量；供方—月份—数量、供方—材料—数量；……，在实际运行中，可根据需要选用。

    从台帐，到表格，在上一节课中已经提到，本课从实现报表的两个思路上进行导论：一是用函数作报表进行分析，二是用数据透视表作报表进行分析。

1.    用函数作报表与分析

    用函数作报表与分析，是指利用函数计算，从台帐中取得数据，作报表进行作图与分析。制作报表时，进行条件求和，制作一维表格，进行合并条件求和，制作二维表格。本课着重研究二维表格。图4-2就是通过合并条件求和，从图4-1中取得数据所制成的二维表格。现具体讨论如下：

    在台帐或一些表格中，往往登录了时间，在具体统计时，还要用月份作为要素进行分析，这时，可以用函数将时间转换成月份。

    合并条件求和，包含两个方面，在台帐中，将两个要素（条件）合并成一个要素（条件），在报表计算时，将两个要素（条件）合并成一个要素（条件），再用条件求和公式以合并后的条件求和。

    在表4-1中：

    K3：=CONCATENATE(F3,L3)   （将供方E8与月份1合并）

    L3：=MONTH(B3)             （2010-1-5的月份是1）

    以填充柄拖拽K3：L3至Kn：Ln



图4-1

    在图4-2中，是一张按“供方—月份—数量”设计的统计表，是一张二维表格。单元格区域P4：AA11是通过合并后的条件进行求和，求和后进行合计计算。AD3：AD13是从报表中调出一列数，选中“O3：O13,AD3：AD13”，作右边如合计状态的柱形图，用滚动条控制AD1，以取得不同的数字，实现动态分析。同理，调出一行数，作出左边的图形。

    具体操作流程：

    在图4-3中：

    AG4：=CONCATENATE($AF4,AG$3)    （合并条件，为条件求和作准备）

    以填充柄拖拽AG4至AR13

    在图4-2中：

    PC4：=SUMIF($K$3:$K$29,AG4,$G$3:$G$29)   （以合并后的条件求和）

    以填充柄拖拽PC4至AA13

    AB4：=SUM(P4:AA4)

    以填充柄拖拽AB4至AB13

    P14：=SUM(P4:P13)

    以填充柄拖拽P14至AB14

    AD3：=INDEX(P$3:AB$13,N3,AD$1)   （查找第几行与第几列的数）

    以填充柄拖拽AD3至AD13

    O16：=INDEX($O4:$AA14,$Q15,O1)

    以填充柄拖拽O16至AA16

    滚动条的作法与格式：

    通过“视图→工具栏→窗体→滚动条”作滚动条。以右图为例，对滚动条进行格式：“击右键→设置控件格式：最小值：0，最大值：13，步长：1，单元格链接：$AD$1”，这样，就达到了以滚动条对单元格$AD$1的控制，每单击一次，步长为1，使数据在1至13中变化，从而调出了不同行的数据，实现了动态分析。

    作图与格式略。



图4-2



图4-3

2.    用数据透视表作报表与分析

    利用数据透视表，对数据进行统计分析，功能十分强大，应用便利快捷。本课以数据透视表的方法，求作二维报表。

    如单击图4-1中的任意一个单元格：“数据→数据透视表→下一步→新建或现有工作表→布局→行：供方，列：月份，数据：数量→确定”，就生成了一张报表如图4-4中上半部分。利用数据透视表也可进行作图，但这里是为了如4-2那样进行动态分析，所以在图4-4的下半部分进行了数据转换的计算：

    N16：=N3

    以填充柄拖拽N16至AA27

    这样就可以利用滚动条件调出一行或一列进行数据的动态分析了。



图4-4

    图4-5是利用数据透视表作排列图。这里是利用数据透视表生成的一张一维表格，布局是：列：供方，数据：数量，是“供方—数量”的要素组合。数据透视表含有降序功能：“对供方下方的任一单元格→击右键→字段设置→高级→降序→使用字段：数量→确定”。为了作排列图，进行“由数据透视表作排列图换算”：

    AE4：=AC4

    以填充柄拖拽AE4至AF13

    编辑公式计算：累积数、80%、90%、100%，具体公式、作图与格式略。



图4-5

    




11/21/11--17:42: 3. 小议论 (chan 2584942)

    

3.    小议论

    制作工具的思路，有时会由合到分，如一份台帐，含有多个条件，按不同条件求报表；有时会由分到合，如对单一零件的台帐进行汇总分析。有时也可能是有分有合。可根据实际，灵活多变，不拘泥一式。如从分到合，定期每月从一个系统中导入数据到Excel 中进行分析，全年再进行汇总分析时，将每月导入的数据设成统一的格式，对全年要的数据“打包”，对这个“过程”进行“复制—粘贴”成十二个月的表格，设计汇总表，把“打包”的数据汇总过来进行分析与作图。不要小瞧这种思路，任何再好的系统，不管查询功能多强大，不管定向报表多完善，总会有要从系统中导入数据进行分析的情况。

    用函数作报表与分析和用数据透视表进行统计分析，各有所长，相辅相成。函数法制成报表，会一劳永逸，台帐变化，报表数据变化，图形也随之变化，很适宜专业人员操作。数据透视表法，功能强大，灵活多变，但每要进行一次分析，就要进行一次操作，不过，这很适合领导层对数据进行分析。二者又有共性的地方，就是按要素或条件进行统计与分析，对要素进行组合，要素设计不到位，就不可能有应有的报表。所以，对要素的设计与管理是非常重要的，不可不注意。

    电脑功能十分强大，我们只能掌握其中一小部分。Excel的功能十分强大，我们只能掌握其中一小部分。如果我们掌握了排序、自动筛选和从台帐到报表到作图的分析的方法，就会很大程度上应付日常工作分析的需要。

电脑应用于管理，会带来管理的变革，规范和提升管理。财务管理软件、ERP管理软件、OA管理软件的应用会越来越多，最后终究还要解决“落地”的问题，即对各平台中的数据，要能综合提取分析与应用。要实现这一目的，关键在思路，以上所介绍的方法，可以提高这种思路。我们有个这样的实践，在OA策划与实施中，将SAP中有关顾客反馈的数据，调到OA中按顾客、供方、产品、质量问题、部门、工程师等要素进行分析，并作了排列图，这说明，在OA中对方针目标考核、绩效考核等跨平台数据的综合分析是完全能够实现的。要实现这种思路，关键在企业内部，因为内部最了解本身的流程。如果企业内部能掌握上述所介绍的在Excel进行数据分析的方法，就能帮助我们设计和分析有效的数据流，譬如说，要设计一份完善的台帐，就得了解报表的需求，不然就不是一份完美的台帐，缺这少那，要设计一份完美的报表，就得有完善的输入，这样才是一个完整的过程，不然会事倍功半。

    在系统设计中一个要注意的问题就是了解数据流与工作流。数据流是首要的，数据流确定了，才能确定工作流。数据流有相对的稳定期，工作流程变化比较大，首先要设计好数据流。




11/28/11--00:26: 第五课 常用统计量 (chan 2584942)

     

第五课    常用统计量

    从第五课开始，围绕如何在Excel中制作质量管理常用工具展开讨论。例题多数选自上海质量管理科学研究院编著的《六西格码实施技巧》，以后文中就讲书中例题，如不同会另外说明。

    样本来自总体，因此样本中含有总体的信息。

    但这些信息是分散的，为了把这些分散的信息集中起来反映总体特征，需要对样本进行加工，一种有效的办法就是构成样本函数，不同的函数可以反映总体的不同特征。

    我们把不含有未知参数的样本函数称为统计量。样本统计量可以分为两类：一类表示数据的集中位置，如平均值、中位数等；一类表示数据的分散程度，如极差、标准差等。

    设x1、x2、x3、……、xn是来自总体的一个样本，则常用的统计量有如下几种，见表5-1 。



表5-1

    图5-1和图5-2是选自书中的两道例题。一道是常用核计量，一道是描述性统计量。如果利用手工计算，会很烦琐。这里用函数计算，非常方便。我们设计成一定的格式，设计输入区与输出区，这里输入区预留了50个数据的位置，只要输入或删除数据，输出区就会自动计算。这种表达方式，在今后的工具中会不断采用。这些统计量，在今后的一些工具中也会用到。

图5-1：

A9：=COUNT(A2:J6)

B9：=AVERAGE(A2:J6)

C9：=VAR(A2:J6)

D9：=STDEV(A2:J6)

E9：=MEDIAN(A2:J6)

F9：=MAX(A2:J6)-MIN(A2:J6)

图5-2：

A9：=COUNTA(A2:J6)

B9：=AVERAGE(A2:J6)

C9：=MEDIAN(A2:J6)

D9：=TRIMMEAN(A2:J6,1/9)

E9：=STDEV(A2:J6)

F9：=(1/A9^0.5)*E9

G9：=MIN(A2:J6)

H9：=MAX(A2:J6)

I9：=QUARTILE(A2:J6,1)

J9：=QUARTILE(A2:J6,3)



图5-1



图5-2

 

 




11/30/11--16:48: 第六课 散布图 (chan 2584942)

     

第六课   散布图

1.散布图

    散布图，也叫相关图。它是表示两个变量变化关系的图。

    散布图是由一个纵坐标、一个横坐标和很多散布的点子组成。

    从散布图上的点子分布状况，可以观察分析出两个变量之间是否有相关关系r，以及关系的密切程度如何。

    相关系数r用于表明因素间是否相关以及这种相关的程度，相关系数r的大小介于-1和1之间。一般地说，r的绝对值大于0.7，则表示两个变量强相关；r的绝对值大于0.4、小于0.7的则表示两个变量中度相关；r的绝对值大于0.2、小于0.4的则表示两个变量弱相关。通常相关系数的绝对值大于0.7的要进一步的检验。

    相关系数的平方：r²称为决定系数，它反映了输出变量（y）变化中由x因素变动引起的部分所占的数量或百分比。如复印机保养时间与故障存在明显的正相关关系，其中y=0.72，r²=0.52，表示大约有50%的故障增长与保养时间间隔有关。注意对r和r²如何解释或做出何种反映取决于分析的目的和数据类型。在Excel中制作散布图时，可以利用函数求出相关系数r和r的绝对值，再编辑公式求出r²。

2.例题

    我们结合书中例题并利用函数计算进一步开展讨论：

    由专业知识知道，合金强度y(×107Pa)与合金中碳的含量x(%)有关。为了生产强度满足用户需要的合金，在冶金时如何控制碳的含量？在冶炼过程中通过试验收集到12组数据如图6-1。

在图中先作了回归直线，对回归在下一课再进一步研究。

    如图：B3：C14是输入区，表示了各点的坐标，在直角坐标系中，一组坐标则对应着一个点，这样，在Excel中就可以利用图表向导中的“XY散点图、散点图：比较成对的散点图”作散布图。E2：J3是通过插入函数进行计算，求出：相关系数r、r的绝对值、决定系数R²、利用r的绝对值大于用IF函数作“判定”、截距、斜率。有了截距和斜率，就可以求出回归方程，在D3：D14中求出当X等于几的对应的Y值，再以B3：B14为X轴，作回归直线。

    具体计算：

E3：=CORREL(B3:B14,C3:C14)

F3：=ABS(E3)

G3：=E3^2

H3：

=IF(E3<=0.2,"不相关",IF(E3<=0.4,"弱相关",IF(E3<=0.7,"中度相关",IF(E3>0.7,"强相关"))))

I3：=INTERCEPT(C3:C14,B3:B14)

J3：=SLOPE(C3:C14,B3:B14)

D3：=J$3*B3+I$3

以填充柄将D3快速填充至D14

3.作图

    作图有两种方法：添加趋势线、回归式法。

    添加趋势线：

    选中B3：C14

    利用“图表向导→XY散点图：散点图。比较成对的数值”进行作图。

    添加趋势线：

    点住散布图中的任意一点，击右键→添加趋势线→类型：线性（L）

    对趋势线格式：

    点住趋势线→击右键→趋势线格式→ 选项：勾选显示公式（E）、勾选显示R平方值（R）

    回归式法：

    单元格区域D3：D14中的数据，是根据回归式所求得的Y值。

    选中B3：D14

    利用“图表向导→XY散点图：散点图。比较成对的数值”进行作图，这时对直线作的也是散点图，只要对直线的图表类型改变为“XY散点图：无数据点平滑散点图”，就成为直线了。



图6-1




11/30/11--17:15: 第七课 回归分析 (chan 2584942)

  

第七课    回归分析

1.回归直线与分析

    两个变量如果存在着显著的相关关系，对于变量X，虽然不是一个确定的Y值与之对应，但Y值总在一个范围内，而且越靠近平均值出现的可能性越大。通常用一元线性回归方程y=ax+b来表示这个估计值。方程所代表的直线为y对x的回归直线，它是与全部点子最接近的直线。

    过去，是用中线法在散布图中作回归直线。现在是通过Excel中的图表向导功能作图的，上一课散布图中已作过讨论。本课是在散布图的基础上进一步开展研究，增加了对回归方程的相关系数检验、方差分析和利用回归方程做预测三个内容。本课进行研究时，对相关系数检验，可进一步参照中国质量管理协会研究与培训中心编著的《质量管理常用总计技术与方法》回归分析中的相关内容。对方差分析将在后边会进一步开展研究，本课仅是应用。

2.版面设计如表7-1：

单元格区域B3：D14的内容和散布图一样。

在B3：C14是输入区，输入测量的数据。

在D3：D14中是通过回归方程计算的Y值：

D3：=F$4*B3+F$3

以填充柄将D3快速填充至D14

相关参数计算及预测

计算出常用的统计量：

F2：=CORREL(B3:B14,C3:C14)

F3：=INTERCEPT(C3:C14,B3:B14)

F4：=SLOPE(C3:C14,B3:B14)

F5：=AVERAGE(C3:C14)

F6：=AVERAGE(B3:B14)

F7：0.16

F8：=FORECAST(F7,C3:C14,B3:B14)

F9：=F8+2.228*(B23/(12-2))^0.5*(1+1/12+(F7-F6)^2/SUM(J3:J14))^0.5

F10：=F8-2.228*(B23/(12-2))^0.5*(1+1/12+(F7-F6)^2/SUM(J3:J14))^0.5

方差分析平方和中间计算

G3：=(C3-F$5)^2

H3：=(D3-C3)^2

I3：=(D3-F$5)^2

以填充柄将G3：I3快速填充至G14：I14

预测区间中间计算

    两条曲线的区域为预测区，要作出两条预测的曲线，就要求出方程和求出对应的Y点坐标值，在单元格区域L3：L14和M3：M14中求出，编辑K3中的公式所依据的公式如图7-1，（参照书中10页：利用回归方程做预测）：



图7-1

J3：=(B3-F$6)^2

K3：=2.228 * (B$23/(12-2))^0.5 *(1+1/12+J3/SUM(J$3:J$14))^0.5（SE= B$23）

L3：=D3+K3

M3：=D3-K3

以填充柄将J3：M3快速填充至J14：M14

相关系数检验

A19：=12-2

B19：0.576    （查相关系数临界表  n-2=10  表7-1由网上查得，在中国质量管理协会研究与培训中心编著的《质量管理常用总计技术与方法》一书中126页也有此表）

C19：0.708 

D19：=ABS(E2)

E19：=IF(D19>C19,"线性相关高度显著",IF(D19>B19,"线性相关显著","相关不显著"))

 

表7-1

方差分析表（P104）

B22：=SUM(I3:I14)

B23：=SUM(H3:H14)    （即图7-1公式中的SE）       

B24：=SUM(G3:G14)

C22：1

C23：=C24-1

C24：=12-10.

D22：=B22/C22

D23：=B23/C23

E22：=D22/D23

F22：=FDIST(E22,C22,C23)



表7-2

3.作图

     选中B3：D14，L3：M14

    利用“图表向导→XY散点图：散点图。比较成对的数值”进行作图，这时对三条线作的也是散点图，只要对三条线的图表类型改变为“XY散点图：无数据点平滑散点图”，就成为三条线了。见图7-2



图7-2

1.    讨论

    仔细了解公式的涵义，对理解概念会有帮助。如果不理解，就是以本课内容也能制作出工具。要注意查相关系数临界表时，注意n的值，在单元格区域A19：C19进行手工输入。

    本课内容，如果是教师在讲课时利用，可能会如虎添翼，既有理论，又有实际的演算，而这种演算是靠公式和函数来完成的，快捷方便，演示性强，如果手工计算，工作量大，如果利用专用软件配合讲课，又会缺少中间的演算过程。

    我想，本课内容如果出自专家的讲解，定是丰富多彩。

 

   

    




12/05/11--00:49: 第八课 直方图--1 (chan 2584942)

     

第八课    直方图

1.什么是直方图

    直方图是通过对数据加工整理,从而分析和掌握质量数据分布情况和估算工序不合格品率的一种图形。将全部数据分成若干组，以组距为底边，以该组距相对应的频次或频率为高按比例所构成的若干图形，即为直方形。

2.直方图的作法：

    传统的手工作图，是采取频数分布表的方法进行的。其计算烦琐，作图麻烦。现在Excel中进行作图，计算简单，作图方便。

    上边说道，将全部数据分成若干组，以组距为底边，在Excel中进行作图的概念就是建立在直角坐标系中作图，组距就是X轴的刻度，对于刻度，有时是小数，有时是自然数，有时是整数，有时是标准差的倍数，完全可以根据研究的需要选择，甚至对刻度可以用滚动条进行控制。

现在以书中例题7.4.1 和7.4.2进行作图。

例题7.4.1：

设计表格并计算如下：



表8-1

在A2：J11中输入抽样数据。

利用函数或公式求相关统计量：

A13：=MAX(A2:J11)       （求最大值）

B13：=MIN(A2:J11)        （求最小值）

C13：=A13-B13           （求极差）

D13：9                   （查表8-2：组数k参照表得）

E13：=C13/D13

F13：3                    （确定组距）

在表8-3单元格区域L2：DJ12中是为作图进行的中间计算（表8-3只取到U12）：

L3：=B13-0.5

L4：=L3+F$13             

以填充柄将L4快速填充至L12  （建X轴）

O2：=A2  （在O2：DJ2中，将A2：J11中的测量数据横向展开）

P2：=B2

……

Y2：=A3

Z2：=B3

……

DJ2：=J11

O4：=IF(AND(O$2>$L3,O$2<$L4),1,"")

（O2为第一个测量数342，当O2大于331.5且小于334.5时，为1，否则为即空白）

以填充柄将O4快速填充至DJ12   

M4：=SUM(O5:DJ5)    

以填充柄将M4快速填充至M12

M13：=SUM(M3:M12)

N4：=M4/M$13

以填充柄将N4快速填充至N12

N13：=SUM(N3:N12)

作图：

选中N3：N12，以“图表向导，柱形图，簇状柱形图”进行作频率直方图。注意 “系列，分类X轴标志（T）：='7.4.1'!$L$3:$L$12”。图形格式略。 

组数k的参照表

数据数目	组数K
40～99	6～8
100～200	8～10
201～500	9～11
501～1000	10～13
1000以上	12～15

表8-2



表8-3



图8-1




12/05/11--00:52: 第八课 直方图--2 (chan 2584942)

书中例题：7.4.2

    数据的变换改变直方图的形状。元素的照射会引起动物（人也一样）的细胞分裂，从而对身体引发损伤。这里细胞分裂时间（interdivision  time 简称IDT）是重要指标。现记录40个细胞的分裂时间IDT（Envir Research  1983  PP.34～43）列于表8-4单元格区域B3：B42中，把它分为七个区间，组距为10，作直方图，见图8-2，从图上是偏向分布。若对每个IDT取十进对数后再作直方图，见图8-3，就近似于正态分布了。

    根据书中题意制表与计算。表格分三部份内容：

   “细胞分裂IDT及其对数”：输入IDT，并进行十进对数转换。分别对IDT和十进对数转换的数求最大值和最小值，从而确定坐标刻度分别为10和0.1 。

在B3：B42中输入测量的数据。

C3：=LOG10(B3)      (十进对数转换)

以填充柄将C3快速填充至C42

B43 ：=MAX(B3:B42)

B44： =MIN(B3:B42)

B45 ：10

C43：=MAX(C3:C42)

C44：=MIN(C3:C42)

C45：0.1

     “a)变换前作图计算”：建立X轴，坐标轴刻度为10（B45中的值），求频次、频率、对B3：B42中的数以10进行进位（取整），对频数与频率分别求和。

E3：=CEILING(B44,B45)     （以最小值进行10进位作为X轴的首项）

E4：=E3+B$45              （首项加10，等差数列，公差为10）

以填充柄将E4快速填充至E9

H3：=CEILING(B3,B$45)    （对B3进行10进位）

以填充柄将H3快速填充至H42

F3：=COUNTIF(H$3:H$42,E3) （在H3:H42中，以E3（10＜E3≤20）为条件求个数）

以填充柄将F3快速填充至F9

F10：=SUM(F3:F9)

G3：=F3/F$10               （求频率）

以填充柄将G3快速填充至G9

G10：=SUM(G3:G9)

     “b)变换后作图计算”：建立X轴，坐标轴刻度为0.1（C45中的值），求频次、频率、对C3：C42中的数以10进行进位（取整），对频数与频率分别求和。

I3：=CEILING(C44,C$45)

I4：=I3+C$45

以填充柄将I4快速填充至I10

J3：=COUNTIF(L$3:L$42,I3)

以填充柄将J3快速填充至J10

J11：=SUM(J3:J10)

K3：=J3/J$11

以填充柄将K3快速填充至K10

K11：=SUM(K3:K10)

L3：=CEILING(C3,C$45)

以填充柄将L3快速填充至L42



表8-4



图8-2



图8-3

    书中进一步说：这个例子显示，变换可以改变频率直方图。这就启示我们，当人们遇到偏态分布时，能否找到一个变换，使变换后的直方图近似于中间高，两边低，左右对称。不少人实现了这个愿望，所用变换大多是y=lnx,y=x^1/2,y=x^-1等。 

3.讨论

    在作直方图时，重点掌握如何确定X坐标轴的刻度，在图8-1中，X坐标轴的刻度是通过过去手工作图时的方法求得的，是小数，因为对频次是靠数数得到的，测量值要落在坐标轴的刻度之间。

    图8-2中X坐标轴的刻度是10，是整数。图8-3中，是0.1，这里虽然也是小数，如对 0.03相对于0.1进位，通俗地说是取整，这里用到函数CEILING来实现进位功能，在进位后，再以函数COUNTIF计算某范围内符合条件的单元格的个数来求频次。这种作图方法，相对于图8-1的作法就简单多了，而且坐标轴的刻度是整数，数据分段清晰。这里作介绍时好像难以理解，如果经过一次练习后就容易体会了。如对进位的数用滚动条来控制，就可以随时改变坐标轴的刻度，以取得满意的图形。

    在后边工序能力分析时，在机械加工中，取刻度为一个测量单位，即为1，就直接用函数COUNTIF计算某范围内符合条件的单元格的个数来求频次。

    这里的Y轴的数值是频次或频率。在作排列图是Y轴的数值是频次或频数。

    因此，在电脑中作图，可以不必拘泥于传统思维，是灵活多变的。这就要求传统的教材在电脑广泛应用于管理后应不断进行改革。对于黑带、绿带老师在六西格玛实施中，如果掌握了在Excel中作质量管理常用工具图的方法，可能会是如虎添翼。

    




12/05/11--23:04: 第九课 点图 (chan 2584942)

    

第九课    点图

1.什么是点图

将全部数据分成若干组，以组距为底边，以该组距相应的频次用点来表示的图形，即为点图（图9-2）。

点图是直方图的（或柱形图）另一种表现形式。

2.点图的作法

    我们在研究散布图时已经知道，在直角坐标系中，已知一个点的坐标（x,y），就对应着一个点。作点图，就是应用这样的原理。

    下边将作直方图和点图进行对照研究。

    表9-1中的例题是笔者在对供方工序能力进行考察时所收集到的一组数据，为了作图，设计如表9-1。

B3：K6是输入区，输入收集的数据。

求最大值和最小值，为作直方图建立X轴时打基础。

C7：=MAX(B3:K6)

E7：=MIN(B3:K6)

M3：N14是为作直方图进行的中间计算，这里坐标X轴的刻度取1：

M4：=E7-1      （最小值减1，作X轴的首项）

M5：=M4+1     （刻度1）

以填充柄将M5快速填充至M14   （建立了X轴）

以函数COUNTIF求频次：

N4：=COUNTIF(B$3:K$6,M4)

以填充柄将N4快速填充至N14

选中N4：N14，以“图表向导，柱形图，簇状柱形图”进行作频次直方图。注意 “系列，分类X轴标志（T）：=函数输入!$M$4:$M$14”。图形格式略。

P3：Y14是为了作点图所进行的中间计算：

在P4：P14中输入1、2、3、……、11，建立点图的X轴

在Q3：Y3中输入1、2、3、……、9，建立作点图的“中间参照标准”，为用IF函数求值时建立条件。

在Q4：Y14中的数据，可以手工输入或用函数进行计算。

手工输入以频次为依据，当频次为1时，输入1；为2时，输入1、2；为5时，输入1、2、3、4、5，以此类推。

函数计算：

Q4：=IF($N4>=Q$3,Q$3,"")    （当N4>=Q3，等于Q3，否则为""，Q3为中间参照标准）

以填充柄将Q4快速填充至Y14

作点图：

    “选中：P4：Q14→图表向导→XY散点图：散点图。比较成对的数值→系列：输入：名称、X值（X）：=函数输入!$P$4:$P$14、Y值（Y）：=函数输入!$P$4:$P$14→勾销图例→完成”。这样，作了Q列数据的点，后边，只要用拖拽添加法就可，即击活图形，用鼠标左键拖拽P4：Q14右下角的边框进行添加，然后对数据点格式。其它格式略。



表9-1



图9-1



图9-2 

1.    讨论

    将点图与直方图进行对照，比较直观。在作法上，明显可见，作点图比直方图复杂多了，如果不是特殊需要，作直方图就可。当需要作点图，而不是作模版时，对表9-1中Q4：Y14中的值由手工输入，这样，作图方便，直接选中P4：Y14利用“XY散点图：散点图。比较成对的数值”作图就可。

    这里作直方图的坐标X轴的刻度就是1，作的直方图清晰，哪个尺寸的频次是多少，一目了然，在使用中，会渐渐地体会到在机械加工中作直方图时，采取这种方法就不错。由此也可见，在Excel中进行数据分析，灵活性强，不必拘泥于一式。

 

    




12/05/11--23:08: 第十课 正态分布图 (chan 2584942)

     

第十课    正态分布图

1.正态分布

    产品质量虽然是波动的，但正常波动是有一定规律的，即存在着一种分布，形成一个分布带，这个分布带的范围反映了产品的精度。

    如正态分布的图形是一条中间高、两边低的“钟形”状态曲线，它具有集中性、对称性等特点。

    正态分布是可以用函数形式来表示的，其密度函数可写成：



    正态分布是由它的平均数μ和标准差σ唯一决定的，常把它记为N(μ, σ²)

2.正态分布图

    正态分布函数式常令人望而却步，如果对一组数先算出它的平均数μ和标准差σ，再算出不同X下的Y值，再通过“描点”作图，可想是一件多么辛苦的事。

    但在Excel中作图却是一件十分轻松的趣事。

    图10-1和图10-2是一张表格，两种状态。先看图10-1，B3中的公式表示为：

    Y=NORMDIST(A3,E$2,F$2,D$2)

    在这个公式中，A3是变量X, E$2是平均值，D$2是标准差，D$2是单元格D2中值，由“窗体→复选框”控制，当不打勾时，为FALSE，Y值为概率密度函数，作PDF图如图10-1，当打勾时，为TRUE，Y值为累积分布函数，作CDF图如图10-2，通过复选框实现两种函数、两个图形的转换。

    作图与格式略。



图10-1



图10-2

    研究正态分布图，关键是掌握平均数μ和标准差σ与图形的关系，平均值不变，标准差变化，图形的胖瘦发生变化，表示数据的分布发生变化；标准差不变，平均值变化，图形的位置发生变化，表示数据的偏离发生变化。这对理解工序能力指数的计算很重要。为了理解上述涵义，在此设计了表10-1，作图10-3 。

     从图10-3中看，中间上下三个图形，表示平均值不变，标准差变化，图形的胖瘦发生变化。

     高度处于中等的左右三个图形，表示标准差不变，平均值变化，图形的位置发生变化。

    以上是从图形的静态分析，如果在Excel作图，选取不同的区域会得到不同的图形，或先作C列的第一个图，然后拖拽法增减，会看出动态的变化。

    表10-1的计算十分便捷：

    C5：=NORMDIST($B5,C$3,C$4,FALSE)

    以填充柄拖拽C5至H24

    作图：选中B5：H24,以图表向导、XY散点图：无数据点平滑散点图作图。图形格式略。



表10-1



图10-3

3.    讨论：

    在数据分析中，正态分布是难点，也是重点。如果我们紧紧把握住正态分布函数NORMDIST的应用，建立好X轴，紧扣住平均值、标准差，并把握住当为FALSE时，为概率密度函数，当为TRUE，为累积分布函数，经常结合实际应用，会逐步帮助我们对正态分布的认识。

    动与静是一对矛盾的对立统一。把静态的东西尽可能动起来，有利于分析问题。所以，本课通过图10-1和10-2动态的切换，帮助对概率密度函数和累积分布函数的理解。对图10-3，虽然是静态的，我们在脑子里也把它动起来，横向看，平均值在变而带来位置在变，纵向看，标准差在变而带来胖瘦在变。对表10-1，如果用滚动条进行控制，调出一行行，来作图，就会实现动态分析。

    下边请看图10-4，仍然采用了作点图的数据。中间计算区内隐藏了作点图的部份，在蓝色的输入区内输入采集的数据，利用函数求出最大值、最小值、平均值、标准差。在中间计算区内建立X轴，分别计算频次、频率、正态分布图的Y值。作频次直方图、频率直方图与正态分布图在一起的图形、点图，进行对比，表示同一组数据的不同表现形式，而频率直方图与正态分布图（概率密度）更有着内在联系，不妨这样说，将输入区的数据无限增加，坐标轴的刻度无限减小，这时的频率直方图的顶点的连线就是正态分布图（概率密度图？），至此，什么是正态分布图就呈出水面了!

    如果将直方图、正态分布图、再加上规格线，进行工序能力分析的图形就水到渠成。欲知工序能力分析如何，且听下一节课分解。



图10-4